Aggiungere un collegamento ad un programma

Aggiungere un collegamento ad un programma
Sul Desktop, nel Menu Avvio, nel Menu Avvio/Programmi o in Esecuzione Automatica

Con la funzione fCreateShellLink del VB6STKIT.DLL (la libreria standard del kit di installazione di Visual Basic 6.0) è possibile aggiungere una icona collegata ad un'applicazione sul Desktop di Windows, nel Menu Avvio, nel Menu Avvio/Programmi ed in Esecuzione Automatica. In questo modo è possibile, per esempio, eseguire l'applicazione direttamente cliccando sull'icona presente nel desktop:

Aggiungere un modulo BAS, ed inserire il seguente codice:

Option Explicit

'Windows API/Dichiarazione
'***********************************************
Public Declare Function fCreateShellLink Lib _
"vb6stkit.dll" (ByVal lpstrFolderName As String, _
ByVal lpstrLinkName As String, _
ByVal lpstrLinkPath As String, _
ByVal lpstrLinkArgs As String, _
ByVal fPrivate As Integer, _
ByVal sParent As String) As Long

'- Il primo parametro specifica a quale cartella deve essere aggiunta
'l'icona (relativo alla posizione della cartella Programmi nel menu di
'Avvio di Windows).
'- Il secondo parametro e relativo al nome che dovrà
'comparire sottostante l'icona.
'- Il terzo parametro specifica l'eseguibile
'o il documento da aprire, completo del percorso.

Public Sub CreateIcon(IconTitle As String, ProgramPath As String, Optional PutWhere As Integer = 0)
If EsisteFile(ProgramPath) Then
    Select Case PutWhere
        Case 0 'Desktop
            fCreateShellLink "..\..\Desktop", IconTitle, ProgramPath, "", -1, "$(Programs)"
        Case 1 'Menu Avvio/Programmi
            fCreateShellLink "..\Programmi", IconTitle, ProgramPath, "", -1, "$(Programs)"
        Case 2 'Menu Avvio
            fCreateShellLink "..", IconTitle, ProgramPath, "", -1, "$(Programs)"
        Case 3 'Menu Avvio/Programmi/Esecuzione Automatica
                    'lancerà automaticamente il programma all'avvio di Windows
            fCreateShellLink "..\Programmi\Esecuzione Automatica", IconTitle, ProgramPath, "", -1, "$(Programs)"
        Case Else 'chiamata invalida, esce fuori
            MsgBox "Tipo parametro non valido, non posso creare il Collegamento.", vbCritical
    End Select
Else
    MsgBox "File o percorso inesistente, non posso creare il Collegamento.", vbCritical
End If
End Sub

'*********************************************
'Controlla se un File esiste o no, restituisce
'True se esiste False se non esiste.
'NomeFile = percorso completo della File
'*********************************************
Function EsisteFile(NomeFile As String) As Boolean
On Local Error GoTo GestoreErrori
'Controlla l'esistenza del file specificato.
If NomeFile <> "" Then
    EsisteFile = IIf(Dir(NomeFile, vbNormal Or vbHidden Or vbReadOnly Or vbSystem) <> "", True, False)
Else
    EsisteFile = False
End If
Exit Function

GestoreErrori:
'Sì è verificato un errore: il file non esiste.
EsisteFile = False
End Function

Per mettere in pratica nel Form principale, inseriamo un CommandButton e nel suo evento Click inseriamo il seguente codice:

Option Explicit

Private Sub Command1_Click()
Dim titoloIcona As String
Dim pathPrg As String
Dim tipoLink As Integer

titoloIcona = "Nuovo CostiInternet"
'titoloIcona è il nome da assegnare al Collegamento
pathPrg = "D:\Francoar\Franknet\CostiInternet\CostiInternet.exe"
'pathPrg è l'applicazione, completa di percorso, che deve essere lanciata dal Collegamento
tipoLink = 0
'tipoLink è la posizione dove si vuole mettere il Collegamento:
'0 = Desktop
'1 = Menu Avvio/Programmi
'2 = Menu Avvio
'3= Menu Avvio/Programmi/Esecuzione Automatica
'     lancerà automaticamente il programma all'avvio di Windows

CreateIcon titoloIcona, pathPrg, tipoLink
End Sub

A questo punto non resta che lanciare il programmino e vedere il risultato.

Testato su: Windows 98, Windows Me, Windows 2000 Professional